USARBotAPI.ComConnection

class ComConnection extends Actor config(USARComServer);

var ComLink link1,link2;
var bool bInit;
var class<ComLink> CLclass;
var config bool bDebug;

function setUp(string id1,string id2)
{
    if(!bInit)
    {
        //Spawn two ComLink objects
        link1=spawn(CLclass,self);
        if(link1!=None)
        {
            link1.setUp(id1);
        }
        link2=spawn(CLclass,self);
        if(link2!=None)
        {
            link2.setUp(id2);
        }
        
        if(link1!=None && link2!=None)
            bInit=true;
        else
        {
            if(bDebug)
                log("ComConnection : Cannot spawn ComLink classes");
        }
    }
}

//Process the requests sent by the robot
function processMessage(string Msg, int Count, byte M[255], string id)
{
    local string Messg, MsgSplit, MsgEnd;
    local string cmdType;
    local int  i;
    
    MsgEnd=";";
    MsgSplit=" ";
    
    if(bDebug) log("ComConnection: "$Msg);
    
    //Removing end of message delim
    i=InStr(Msg,MsgEnd);
    if(i == -1)
    {
        i=Len(Msg);
        log("ComConnection: Recieved Message does not terminate well - "$Msg);
    }
    Msg=left(Msg,i);
    
    if(bDebug)
        log("ComConnection: After removing end of message limiter - "$Msg);

    //Splitting message	
    i=InStr(Msg,MsgSplit);
    if(i==-1)
        i=Len(Msg);
    cmdType=Left(Msg,i);
    cmdType = Caps(cmdType);
    Messg=Mid(Msg,i+1);
    
    //Processing the command
    switch(cmdType)
    {
        case "SEND":
            if(!(ComServer(Owner).isReachable(link1.id,link2.id)))
            {
                if(bDebug) log("ComServer: Lost connectivity between "$link1.id$" and "$link2.id);
                if(id==link1.id)
                {
                    link1.SendText("Fail: Lost connectivity between "$link1.id$" and "$link2.id$";");
                }
                else
                {
                    link2.SendText("Fail: Lost connectivity between "$link1.id$" and "$link2.id$";");
                }
                link1.Close();
                link2.Close();
                link1.bInit=false;
                link2.bInit=false;
                break;
            }
            if(id==link1.id)
            {
                link2.SendBinary(Count,M);
                link1.SendText("OK;");
            }
            else
            {
                link1.SendBinary(Count,M);
                link2.SendText("OK;");
            }
            break;
        case "CLOSE":
            link1.Close();
            link2.Close();
            link1.bInit=false;
            link2.bInit=false;
            break;
        //These should not occur
        case "REGISTER":
        case "LISTEN":
        case "OPEN":
        default:
            if(bDebug) log("ComConnection: Unknown message - "$Msg);
            if(id==link1.id)
            {
                Link1.SendText("Fail: Unknown message;");
            }
            else
            {
                Link2.SendText("Fail: Unknown message;");
            }
    }
}

defaultproperties
{
    CLclass=USARBotApi.ComLink
    bInit=false
    bDebug=true
}