USARBotAPI.ComServer

class ComServer extends TcpLink
        config(USARComServer);


var config int ListenPort;
var int MaxConnections;

var string gameClass;
var bool bBound;
var config bool bDebug;

var int ConnectionCount;

var array<string> ParsedMessg;
var string MsgSplit;
var string MsgEnd;
var string PartMsg;

struct StrPair {
    var string str1;
    var string str2;
};

// The names and IP's of robots registered
var array<StrPair> RegRobots;
var int numReg;
// The name and port of robots which are listening
var array<StrPair> Listening;
var int numListen;
//Connections between two robots set up by the server
var array<ComConnection> Connected;
var int numCon;

//Variables controlling the dropping of packets
var config float ePdo;
var config float eDo;
var config float eN;
var config float eCutoff;

//Check if a robot is registered with the server
function bool isRegistered(string name)
{
    local int i;
    i=0;
    while(i<numReg)
    {
        if(name==RegRobots[i].str1)
        {
            return true;
        }
        i++;
    }
    return false;
}

//Check if a robot is listening
function bool isListening(string name)
{
    local int i;
    i=0;
    while(i<numListen)
    {
        if(name==Listening[i].str1)
        {
            return true;
        }
        i++;
    }
    return false;
}

//Check if a robot is listening at a specific port
function bool isListening2(string name, string port)
{
    local int i;
    i=0;
    while(i<numListen)
    {
        if(name==Listening[i].str1 && port==Listening[i].str2)
        {
            return true;
        }
        i++;
    }
    return false;
}

//Get the index of the robot listening at the specific port
function int getListenerNum(string name, string port)
{
    local int i;
    i=0;
    while(i<numListen)
    {
        if(name==Listening[i].str1 && port==Listening[i].str2)
        {
            return i;
        }
        i++;
    }
    return -1;
}

//Get the IP of the robot
function string getRobotIP(string name)
{
    local int i;
    i=0;
    while(i<numReg)
    {
        if(name==RegRobots[i].str1)
        {
            return RegRobots[i].str2;
        }
        i++;
    }
    return "";
}

//Get the port the robot is listening at
function string getRobotPort(string name)
{
    local int i;
    i=0;
    while(i<numListen)
    {
        if(name==Listening[i].str1)
        {
            return Listening[i].str2;
        }
        i++;
    }
    return "";
}

//Check for connectivity
function bool isReachable(string r1,string r2)
{
    if(bDebug)
        log("ComServer: Cannot get robot information");
    return true;
}

function BeginPlay()
{
    local bool temp;
    Super.BeginPlay();
    LinkMode=MODE_Text;
    if(!bBound)
    {
        BindPort( ListenPort );
        if(bDebug)
            log("ComServer bound to port "$ListenPort);
        temp=Listen();
        if(temp)
            bBound = true;
        else
        {
            if(bDebug)
                log("ComServer: Not able to listen");
        }
    }
}

event ReceivedLine( string Line )
{
    //Parsing the message
    local string cmdType;
    local int attrNum, i;
    local bool b1,b2;
   
    if(bDebug)
        log("ComServer: Recieved Message - "$Line);

    //Removing end of message delim
    i=InStr(Line,MsgEnd);
    if(i == -1)
    {
        i=Len(Line);
        if(bDebug)
            log("ComServer: Recieved Message does not terminate well - "$Line);
    }
    Line=left(Line,i);
    
    if(bDebug)
        log("ComServer: After removing end of message limiter - "$Line);

    //Splitting message	
    attrNum=Split(Line,MsgSplit,ParsedMessg);
    if(bDebug)
        log("ComServer: Message contained "@attrNum$" words");
    
    cmdType=ParsedMessg[0];
    cmdType = Caps(cmdType);
    
    //Processing the command
    switch(cmdType)
    {
        case "REGISTER":
            //Checking for correct message length
            if(attrNum!=3)
            {
                if(bDebug) log("ComServer: Incorrect message length in "$Line);
                SendText("Fail: Incorrect Message;");
                break;
            }
            //Checking if a robot with the same name is registered
            if(isRegistered(ParsedMessg[1]))
            {
                if(bDebug) log("ComServer: Robot with name "$ParsedMessg[1]$" already registerd");
                SendText("Fail: Robot with name "$ParsedMessg[1]$" already registered;");
            }
            //Registering
            RegRobots.insert(numReg,1);
            RegRobots[numReg].str1$=ParsedMessg[1];
            RegRobots[numReg].str2$=ParsedMessg[2];
            if(bDebug)
            {
                log("ComServer: "$RegRobots[numReg].str1$" registered with IP "$RegRobots[numReg].str2);
                log("ComServer: "$(numReg+1)$" robots registered");
            }
            numReg++;
            SendText("OK;");
            break;
        case "LISTEN":
            //Checking for correct message length
            if(attrNum!=3)
            {
                if(bDebug) log("ComServer: Incorrect message length in "$Line);
                SendText("Fail: Incorrect Message;");
                break;
            }
            //Checking if the robot is registered
            if(!isRegistered(ParsedMessg[1]))
            {
                if(bDebug) log("ComServer: Robot "$ParsedMessg[1]$" not registered");
                SendText("Fail: Robot "$ParsedMessg[1]$" not registered;");
                break;
            }
            //Checking if a robot with the same name is listening at the same port
            if(isListening(ParsedMessg[1]))
            {
                if(getRobotPort(ParsedMessg[1])==ParsedMessg[2])
                {
                    if(bDebug) log("ComServer: Robot with name "$ParsedMessg[1]$" already listening at port "$ParsedMessg[2]);
                    SendText("Fail: Robot with name "$ParsedMessg[1]$" already listening at port "$ParsedMessg[2]$";");
                    break;
                }
            }
            //Adding to listening list
            Listening.insert(numListen,1);
            Listening[numListen].str1$=ParsedMessg[1];
            Listening[numListen].str2$=ParsedMessg[2];
            if(bDebug)
            {
                log("ComServer: "$Listening[numListen].str1$" listening at port "$Listening[numListen].str2);
                log("ComServer: "$(numListen+1)$" robots listening");
            }
            numListen++;
            SendText("OK;");
            break;
        case "OPEN":
            //Checking for correct message length
            if(attrNum!=5)
            {
                if(bDebug) log("ComServer: Incorrect message length in "$Line);
                SendText("Fail: Incorrect Message;");
                break;
            }
            //Check if host is listening on specified port
            if(!isListening2(ParsedMessg[3],ParsedMessg[4]))
            {
                if(bDebug) log("ComServer: "$ParsedMessg[3]$" not listening on port "$ParsedMessg[4]);
                SendText("Fail: "$ParsedMessg[3]$" not listening on port "$ParsedMessg[4]$";");
                break;
            }
            //Check for connectivity
            if(!isReachable(ParsedMessg[1],ParsedMessg[3]))
            {
                if(bDebug) log("ComServer: Cannot connect to "$ParsedMessg[3]);
                SendText("Fail: Cannot connect to "$ParsedMessg[3]$";");
                break;
            }
            //Try setting up the needed connections
            Connected.insert(numCon,1);
            Connected[numCon]=spawn(class'ComConnection',self);
            Connected[numCon].setUp(ParsedMessg[3],ParsedMessg[1]);
            
            Connected[numCon].link1.Connect(getRobotIP(ParsedMessg[1]),ParsedMessg[2]);
            Connected[numCon].link2.Connect(getRobotIP(ParsedMessg[3]),ParsedMessg[4]);
            
            //Checking if the connection was established
            b1=(Connected[numCon].link1.LinkState==STATE_Connecting || Connected[numCon].link1.LinkState==STATE_Connected);
            b2=(Connected[numCon].link2.LinkState==STATE_Connecting || Connected[numCon].link2.LinkState==STATE_Connected);
            //If the connection was established
            if(b1 && b2)
            {
                //Remove listening robot
                i=getListenerNum(ParsedMessg[3],ParsedMessg[4]);
                Listening.remove(i,1);
                numListen--;
                if(bDebug)
                {
                    log("ComServer: "$ParsedMessg[1]$" connected to "$ParsedMessg[3]);
                    log("ComServer: "$(numCon+1)$" connections created");
                }
                SendText("OK;");
                numCon++;
            }
            else
            {
                Connected.remove(numCon,1);
                if(bDebug)  log("ComServer: "$ParsedMessg[1]$" could not connect to "$ParsedMessg[3]);
                SendText("Fail: Could not establish connection;");
            }
            break;
        //These cases should not occur here
        case "SEND":
        case "CLOSE":
        default:
            if(bDebug) log("ComServer: Unknown message - "$Line);
            SendText("Fail: Unknown message;");
    }
}

//If you recieve text instead of by line
event ReceivedText( string Text )
{
    local int i;
    local string Msg;
    
    i=0;
    if(bDebug)
        log("ComServer: Recieved Text in Server - "$Text);
        
    i=InStr(Text,MsgEnd);
    if(i==-1)               //Incomplete message
    {
        PartMsg$=Text;      //Concatenate
    }
    else
    {
        Msg=PartMsg$Left(Text,i+1);
        PartMsg=Mid(Text,i+1);
        ReceivedLine(Msg);
    }
}

//If you recieve a binary message
event ReceivedBinary( int Count, byte B[255] )
{
    if(bDebug)
        log("ComServer: Recieved some binary message (should not occur)");
}

//Whena connection is accepted
event Accepted()
{
    if(bDebug)
        log("ComServer: Connected to "$IpAddrToString(RemoteAddr));
}

//Closed on other end
event Closed()
{
    local bool temp;
    if(LinkState!=STATE_Listening && LinkState!=STATE_Connecting && LinkState!=STATE_Connected)
    {
        temp=Listen();
    }
    if(bDebug)
    {
        log(temp);
        log(LinkState);
        log("ComServer: Old connection closed, listening for new connections");
    }
}

//called everytime a new botconnection is spawned
event GainedChild( Actor C )
{
}

event LostChild( Actor C )
{
}

defaultproperties
{
     ListenPort=5874
     MaxConnections=64
     bBound=false
     bDebug=true
     ConnectionCount=0
     MsgSplit=" "
     MsgEnd=";"
     numReg=0
     numListen=0
     numCon=0
     PartMsg=""
     ePdo=-50
     eDo=2
     eN=1
     eCutoff=-93
}