USARBot.KNActor

// Network KActor that works on server and client
//
// Simplified form NetKActor http://mods.beyondunreal.com/mod.php?id=200. 
// All credits go to the GoodKarma group. -- Jijun Wang

class KNActor extends KActor placeable;

var KRigidBodyState    KState, KRepState;
var bool               bReceiveStateNew;
var byte               StateCount, LastStateCount;

replication
{
    reliable if(Role == ROLE_Authority) KRepState, StateCount;
}

// This even is for updating the state (position, velocity etc.) of the tire's karma
// body when we get new information from the network.
simulated event bool KUpdateState(out KRigidBodyState newState)
{
    if(Level.NetMode == NM_DedicatedServer || StateCount == LastStateCount)
        return false;

    newState = KrepState;
    LastStateCount = StateCount;
    
    return true;
}

function Tick(float Delta)
{
    Super.Tick(Delta);
    if (Level.NetMode == NM_DedicatedServer)
        PackState();
}

// Pack current state to be sent to the client.
// Should only get called on the server.
function PackState()
{
    local bool bChanged;
    
    if(!KIsAwake())
        return;
    
    KGetRigidBodyState(KState);
    
    bChanged = bChanged || VSize(KRBVecToVector(KState.Position) - KRBVecToVector(KRepState.Position)) > 1.0;
    bChanged = bChanged || VSize(KRBVecToVector(KState.LinVel) - KRBVecToVector(KRepState.LinVel)) > 0.2;
    bChanged = bChanged || VSize(KRBVecToVector(KState.AngVel) - KRBVecToVector(KRepState.AngVel)) > 0.2;

    if(bChanged) {
        KRepState = KState;
        StateCount++;
    }
    
    return;
}

simulated event Bump(Actor Other)
{
    if(!KIsAwake())
        KWake() ;
}

simulated event FellOutOfWorld(eKillZType KillType)
{
    bTearOff = true ;
    SetPhysics(PHYS_None) ;
    bHidden = true ;
}

defaultproperties
{
    bNetNotify=True
    RemoteRole=ROLE_SimulatedProxy
    StaticMesh=StaticMesh'USARSim_VehicleParts_Meshes.Test.TestBody'
    Begin Object Class=KarmaParams Name=KarmaParams0
        KMass=0.500000
        bHighDetailOnly=False
        bClientOnly=False
        bKDoubleTickRate=True
        KFriction=0.500000
        KRestitution=0.200000
        KMaxSpeed=25
        KImpactThreshold=100000.000000
    End Object
    KParams=KarmaParams'USARBot.KNActor.KarmaParams0'
    
    bPathColliding=True
}