USARBot.KNActorFactory

//=============================================================================
// Piper spawner location.
//=============================================================================
class KNActorFactory extends Actor 
    placeable;

var(Factory)    int     Count;
var(Factory)    vector  Range;
var(Factory)    class<KNActor>  KNActorClass;

function PostNetBeginPlay()
{
    local int i;
    local vector v;
    local rotator r;
    local KNActor myActor;
    
    for (i=0;i<Count;i++) {
        v.X = RandRange(-Range.X,Range.X);
        v.Y = RandRange(-Range.Y,Range.Y);
        v.Z = RandRange(0,Range.Z)+20;
        
        r.Pitch=0;
        r.Yaw=RandRange(0,65535);
        r.Roll=0;
        
        myActor = spawn(KNActorClass, , , Location+v, Rotation+r);
    }
}

defaultproperties
{
     bHidden=True
     bNoDelete=True
     RemoteRole=ROLE_None
     Texture=Texture'Engine.S_KVehFact'
     
     Count=10
     Range=(X=200,Y=200,Z=20)
     KNActorClass=class'USARBot.KNBrick'
}