USARBot.MisPkgLinkInfo

class MisPkgLinkInfo extends Object config(USARMisPkg);

struct MountPoint
{
    var string Name;
    var vector Location;
    var string JointType;
    var vector Orientation;
};

var config array<MountPoint> MountPoints;
var config float MaxSpeed;
var config float MaxTorque;
var config float MinRange;
var config float MaxRange;
var class<KActor> ModelClass;


//*********************************************************************************************************************
// getMountPointLocation Function
// ------------------------------
//     Function that returns the location of the mount point passed as a parameter.  This location is the location
//   from the part's origin.
//*********************************************************************************************************************
function vector getMountPointLocation(string MountPointName)
{
    local int i;

    for(i=0; i<MountPoints.Length; i++)
    {
        if(MountPointName == MountPoints[i].Name)
        {
            return MountPoints[i].Location;
        }
    }
}


//*********************************************************************************************************************
// getMountPointJointType Function
// -------------------------------
//     Function that returns the joint type of the mount point passed as a parameter. The joint type can either be
//   "Revolute" or "Prismatic" for a revolute joint and a prismatic joint, respectively.
//*********************************************************************************************************************
function string getMountPointJointType(string MountPointName)
{
    local int i;

    for(i=0; i<MountPoints.Length; i++)
    {
        if(MountPointName == MountPoints[i].Name)
        {
            return MountPoints[i].JointType;
        }
    }
}


//*********************************************************************************************************************
// getMountPointOrientation Function
// -------------------------------
//     Function that returns the joint orientation (local coordinate) of the mount point passed as a parameter.
//*********************************************************************************************************************
function vector getMountPointOrientation(string MountPointName)
{
    local int i;

    for(i=0; i<MountPoints.Length; i++)
    {
        if(MountPointName == MountPoints[i].Name)
        {
            return MountPoints[i].Orientation;
        }
    }
}


//*********************************************************************************************************************
// getConfData Function
// --------------------
//     Function that returns a string with the CONF information of a mission package link.
//*********************************************************************************************************************
function string getConfData(name LinkName, string MountPoint, int LinkNumber)
{
    local string confJointType, confOrientation, confSpeed, confTorque, confMinRange, confMaxRange;

    confJointType = getMountPointJointType(MountPoint);
    confOrientation = string(getMountPointOrientation(MountPoint));
    confSpeed = string(MaxSpeed);
    confTorque = string(MaxTorque);
    confMinRange = string(MinRange);
    confMaxRange = string(MaxRange);

    return "{Link " $ LinkNumber $ "} {JointType " $ confJointType $ "} {MaxSpeed " $ confSpeed $ "} {MaxTorque " $ confTorque $ "} {MinRange " $ confMinRange $ "} {MaxRange " $ confMaxRange $ "}";
}


//*********************************************************************************************************************
// getGeoData Function
// --------------------
//     Function that returns a string with the GEO information of a mission package link.
//*********************************************************************************************************************
function string getGeoData(name LinkName, string geoJointPos, string geoJointRot, int LinkNumber, int ParentLinkNumber)
{
    return "{Link " $ LinkNumber $ "} {ParentLink " $ ParentLinkNumber $ "} {Location " $ geoJointPos $ "} {Orientation " $ geoJointRot $ "}";
}

defaultproperties
{
    MaxSpeed=0.1745
    MaxTorque=20.0
    MinRange=1
    MaxRange=0
}