USARBot.Sensor

class Sensor extends Item abstract;

var config bool HiddenSensor;
var config InterpCurve  OutputCurve;
var config float    Noise;
// Contains Gaussian Random Number generator
var USARUtils utils;
// Variables to be used in the gaussian random number generator
var float Mean;
var float Sigma;

// Whether the sensor data will be sent out in group style or not. Right now,
// all the sensor in the same type are treated as a group
var config bool bUseGroup; 
var config bool bWithTimeStamp;

function Init(String SName, Actor parent, vector position, rotator direction, KVehicle platform, name mount)
{
    Super.Init(SName,parent,position,direction,platform,mount);
    bHidden = HiddenSensor;
    utils = New class'USARUtils';
}

function String GetData()
{
    local string outstring;

    outstring="{Name "$ItemName$"}";

    return outstring;
}

function String GetHead()
{
    local string outstring;

    if (bWithTimeStamp)
        outstring="SEN {Time "$Level.TimeSeconds$"} {Type "$ItemType$"}";
    else
        outstring="SEN {Type "$ItemType$"}";

    return outstring;
}

function String GetConfHead()
{
    local string outstring;

    outstring="CONF {Type "$ItemType$"}";

    return outstring;
}

function String GetConfData()
{
    return "{Name "$ItemName$"}";
}

function string GetGeoHead()
{
    local string outstring;

    outstring="GEO {Type "$ItemType$"}";

    return outstring;
}

function string GetGeoData()
{
    local string outstring;

    if (converter==None)
        outstring="{Name "$ItemName$" Location "$(Location-Base.Location)$" Orientation "$(Rotation-Base.Rotation)$" Mount "$ItemMount$"}";
    else 
        outstring="{Name "$ItemName$" Location "$(converter.Str_LengthVectorFromUU(Location-Base.Location))
                               $" Orientation "$(converter.Str_RotatorFromUU(Rotation-Base.Rotation))
                                     $" Mount "$ItemMount$"}";
    return outstring;
}

defaultproperties
{
    ItemType="Sensor"
    HiddenSensor=true
    Noise=0.001
    DrawType=DT_StaticMesh
    DrawScale=0.1
    StaticMesh=StaticMesh'USARSim_VehicleParts_Meshes.Sensors.Sensor'
    bHardAttach=true
    RemoteRole=ROLE_None
    bUseGroup=false;
        Sigma=0.05
    Mean=0.0
}