USARBotAPI.VizServer

class VizServer extends TcpLink config(USARBotAPI);

var config int ListenPort;
var config int MaxConnections;
var string gameClass;
var bool bBound;
var config bool bDebug;
var int ConnectionCount;

//shouldn't happen
event ReceivedText( string Text )
{
    if(bDebug)
        log("RecievedText in VizServer - "$Text);
}

function BeginPlay()
{
    Super.BeginPlay();

    if(!bBound)

    {
        BindPort( ListenPort );

        if(bDebug)
            log("VizServer bound to port "$ListenPort);
        Listen();
        bBound = true;
    }
}
//should never happen - accepted connections should be forwarded to a botconnection

event Accepted()
{
    if(bDebug)
        log("Accepted connection in VizServer");
}

//called everytime a new botconnection is spawned
event GainedChild( Actor C )
{
    Super.GainedChild(C);
    ConnectionCount++;

    //BotConnection(C).Parent = self;
    // if too many connections, close down listen.

    if(MaxConnections > 0 && ConnectionCount > MaxConnections && LinkState == STATE_Listening)

    {
        if(bDebug)
            Log("VizServer: Too many connections - closing down Listen.");
        Close();
    }
}

event LostChild( Actor C )
{
    Super.LostChild(C);
    ConnectionCount--;

    // if closed due to too many connections, start listening again.

    if(ConnectionCount <= MaxConnections && LinkState != STATE_Listening)
    {
        if(bDebug)
            Log("VizServer: Listening again - connections have been closed.");
        Listen();
    }
}

defaultproperties
{
     ListenPort=3001
     MaxConnections=4
     AcceptClass=Class'USARBotAPI.VizConnection'
}