Onslaught.ONSAttackCraft

//-----------------------------------------------------------
//
//-----------------------------------------------------------
class ONSAttackCraft extends ONSChopperCraft
    placeable;

#exec OBJ LOAD FILE=..\textures\VMVehicles-TX.utx

var()   float                           MaxPitchSpeed;

var()   array<vector>                   TrailEffectPositions;
var     class<ONSAttackCraftExhaust>    TrailEffectClass;
var     array<ONSAttackCraftExhaust>    TrailEffects;

var()   array<vector>                   StreamerEffectOffset;
var     class<ONSAttackCraftStreamer>   StreamerEffectClass;
var     array<ONSAttackCraftStreamer>   StreamerEffect;

var()   range                           StreamerOpacityRamp;
var()   float                           StreamerOpacityChangeRate;
var()   float                           StreamerOpacityMax;
var     float                           StreamerCurrentOpacity;
var     bool                            StreamerActive;

// AI hint
function bool FastVehicle()
{
    return true;
}

function bool Dodge(eDoubleClickDir DoubleClickMove)
{
    if ( FRand() < 0.7 )
    {
        VehicleMovingTime = Level.TimeSeconds + 1;
        Rise = 1;
    }
    return false;
}

function KDriverEnter(Pawn P)
{
    bHeadingInitialized = False;

    Super.KDriverEnter(P);
}

simulated function ClientKDriverEnter(PlayerController PC)
{
    bHeadingInitialized = False;

    Super.ClientKDriverEnter(PC);
}

simulated function SpecialCalcBehindView(PlayerController PC, out actor ViewActor, out vector CameraLocation, out rotator CameraRotation )
{
    local vector CamLookAt, HitLocation, HitNormal, OffsetVector;
    local Actor HitActor;
    local vector x, y, z;

    if (DesiredTPCamDistance < TPCamDistance)
        TPCamDistance = FMax(DesiredTPCamDistance, TPCamDistance - CameraSpeed * (Level.TimeSeconds - LastCameraCalcTime));
    else if (DesiredTPCamDistance > TPCamDistance)
        TPCamDistance = FMin(DesiredTPCamDistance, TPCamDistance + CameraSpeed * (Level.TimeSeconds - LastCameraCalcTime));

    GetAxes(PC.Rotation, x, y, z);
    ViewActor = self;
    CamLookAt = GetCameraLocationStart() + (TPCamLookat >> Rotation) + TPCamWorldOffset;

    OffsetVector = vect(0, 0, 0);
    OffsetVector.X = -1.0 * TPCamDistance;

    CameraLocation = CamLookAt + (OffsetVector >> PC.Rotation);

    HitActor = Trace(HitLocation, HitNormal, CameraLocation, Location, true, vect(40, 40, 40));
    if ( HitActor != None
         && (HitActor.bWorldGeometry || HitActor == GetVehicleBase() || Trace(HitLocation, HitNormal, CameraLocation, Location, false, vect(40, 40, 40)) != None) )
            CameraLocation = HitLocation;

    CameraRotation = Normalize(PC.Rotation + PC.ShakeRot);
    CameraLocation = CameraLocation + PC.ShakeOffset.X * x + PC.ShakeOffset.Y * y + PC.ShakeOffset.Z * z;
}

function Died(Controller Killer, class<DamageType> damageType, vector HitLocation)
{
    local int i;

    if(Level.NetMode != NM_DedicatedServer)
    {
        for(i=0;i<TrailEffects.Length;i++)
            TrailEffects[i].Destroy();
        TrailEffects.Length = 0;

        for(i=0; i<StreamerEffect.Length; i++)
            StreamerEffect[i].Destroy();
        StreamerEffect.Length = 0;
    }

    Super.Died(Killer, damageType, HitLocation);
}

simulated function Destroyed()
{
    local int i;

    if(Level.NetMode != NM_DedicatedServer)
    {
        for(i=0;i<TrailEffects.Length;i++)
            TrailEffects[i].Destroy();
        TrailEffects.Length = 0;

        for(i=0; i<StreamerEffect.Length; i++)
            StreamerEffect[i].Destroy();
        StreamerEffect.Length = 0;
    }

    Super.Destroyed();
}

simulated event DrivingStatusChanged()
{
    local vector RotX, RotY, RotZ;
    local int i;

    Super.DrivingStatusChanged();

    if (bDriving && Level.NetMode != NM_DedicatedServer && !bDropDetail)
    {
        GetAxes(Rotation,RotX,RotY,RotZ);

        if (TrailEffects.Length == 0)
        {
            TrailEffects.Length = TrailEffectPositions.Length;

            for(i=0;i<TrailEffects.Length;i++)
                if (TrailEffects[i] == None)
                {
                    TrailEffects[i] = spawn(TrailEffectClass, self,, Location + (TrailEffectPositions[i] >> Rotation) );
                    TrailEffects[i].SetBase(self);
                    TrailEffects[i].SetRelativeRotation( rot(0,32768,0) );
                }
        }

        if (StreamerEffect.Length == 0)
        {
            StreamerEffect.Length = StreamerEffectOffset.Length;

            for(i=0; i<StreamerEffect.Length; i++)
                if (StreamerEffect[i] == None)
                {
                    StreamerEffect[i] = spawn(StreamerEffectClass, self,, Location + (StreamerEffectOffset[i] >> Rotation) );
                    StreamerEffect[i].SetBase(self);
                }
        }
    }
    else
    {
        if (Level.NetMode != NM_DedicatedServer)
        {
            for(i=0;i<TrailEffects.Length;i++)
               TrailEffects[i].Destroy();

            TrailEffects.Length = 0;

            for(i=0; i<StreamerEffect.Length; i++)
                StreamerEffect[i].Destroy();

            StreamerEffect.Length = 0;
        }
    }
}

simulated function Tick(float DeltaTime)
{
    local float EnginePitch, DesiredOpacity, DeltaOpacity, MaxOpacityChange, ThrustAmount;
    local TrailEmitter T;
    local int i;
    local vector RelVel;
    local bool NewStreamerActive, bIsBehindView;
    local PlayerController PC;

    if(Level.NetMode != NM_DedicatedServer)
    {
        EnginePitch = 64.0 + VSize(Velocity)/MaxPitchSpeed * 32.0;
        SoundPitch = FClamp(EnginePitch, 64, 96);

        RelVel = Velocity << Rotation;

        PC = Level.GetLocalPlayerController();
        if (PC != None && PC.ViewTarget == self)
            bIsBehindView = PC.bBehindView;
        else
            bIsBehindView = True;

        // Adjust Engine FX depending on being drive/velocity
        if (!bIsBehindView)
        {
            for(i=0; i<TrailEffects.Length; i++)
                TrailEffects[i].SetThrustEnabled(false);
        }
        else
        {
            ThrustAmount = FClamp(OutputThrust, 0.0, 1.0);

            for(i=0; i<TrailEffects.Length; i++)
            {
                TrailEffects[i].SetThrustEnabled(true);
                TrailEffects[i].SetThrust(ThrustAmount);
            }
        }

        // Update streamer opacity (limit max change speed)
        DesiredOpacity = (RelVel.X - StreamerOpacityRamp.Min)/(StreamerOpacityRamp.Max - StreamerOpacityRamp.Min);
        DesiredOpacity = FClamp(DesiredOpacity, 0.0, StreamerOpacityMax);

        MaxOpacityChange = DeltaTime * StreamerOpacityChangeRate;

        DeltaOpacity = DesiredOpacity - StreamerCurrentOpacity;
        DeltaOpacity = FClamp(DeltaOpacity, -MaxOpacityChange, MaxOpacityChange);

        if(!bIsBehindView)
            StreamerCurrentOpacity = 0.0;
        else
            StreamerCurrentOpacity += DeltaOpacity;

        if(StreamerCurrentOpacity < 0.01)
            NewStreamerActive = false;
        else
            NewStreamerActive = true;

        for(i=0; i<StreamerEffect.Length; i++)
        {
            if(NewStreamerActive)
            {
                if(!StreamerActive)
                {
                    T = TrailEmitter(StreamerEffect[i].Emitters[0]);
                    T.ResetTrail();
                }

                StreamerEffect[i].Emitters[0].Disabled = false;
                StreamerEffect[i].Emitters[0].Opacity = StreamerCurrentOpacity;
            }
            else
            {
                StreamerEffect[i].Emitters[0].Disabled = true;
                StreamerEffect[i].Emitters[0].Opacity = 0.0;
            }
        }

        StreamerActive = NewStreamerActive;
    }

    Super.Tick(DeltaTime);
}

function float ImpactDamageModifier()
{
    local float Multiplier;
    local vector X, Y, Z;

    GetAxes(Rotation, X, Y, Z);
    if (ImpactInfo.ImpactNorm Dot Z > 0)
        Multiplier = 1-(ImpactInfo.ImpactNorm Dot Z);
    else
        Multiplier = 1.0;

    return Super.ImpactDamageModifier() * Multiplier;
}

function bool RecommendLongRangedAttack()
{
    return true;
}

//FIXME Fix to not be specific to this class after demo
function bool PlaceExitingDriver()
{
    local int i;
    local vector tryPlace, Extent, HitLocation, HitNormal, ZOffset;

    Extent = Driver.default.CollisionRadius * vect(1,1,0);
    Extent *= 2;
    Extent.Z = Driver.default.CollisionHeight;
    ZOffset = Driver.default.CollisionHeight * vect(0,0,1);
    if (Trace(HitLocation, HitNormal, Location + (ZOffset * 6), Location, false, Extent) != None)
        return false;

    //avoid running driver over by placing in direction perpendicular to velocity
    if ( VSize(Velocity) > 100 )
    {
        tryPlace = Normal(Velocity cross vect(0,0,1)) * (CollisionRadius + Driver.default.CollisionRadius ) * 1.25 ;
        if ( FRand() < 0.5 )
            tryPlace *= -1; //randomly prefer other side
        if ( (Trace(HitLocation, HitNormal, Location + tryPlace + ZOffset, Location + ZOffset, false, Extent) == None && Driver.SetLocation(Location + tryPlace + ZOffset))
             || (Trace(HitLocation, HitNormal, Location - tryPlace + ZOffset, Location + ZOffset, false, Extent) == None && Driver.SetLocation(Location - tryPlace + ZOffset)) )
            return true;
    }

    for( i=0; i<ExitPositions.Length; i++)
    {
        if ( ExitPositions[0].Z != 0 )
            ZOffset = Vect(0,0,1) * ExitPositions[0].Z;
        else
            ZOffset = Driver.default.CollisionHeight * vect(0,0,2);

        if ( bRelativeExitPos )
            tryPlace = Location + ( (ExitPositions[i]-ZOffset) >> Rotation) + ZOffset;
        else
            tryPlace = ExitPositions[i];

        // First, do a line check (stops us passing through things on exit).
        if ( bRelativeExitPos && Trace(HitLocation, HitNormal, tryPlace, Location + ZOffset, false, Extent) != None )
            continue;

        // Then see if we can place the player there.
        if ( !Driver.SetLocation(tryPlace) )
            continue;

        return true;
    }
    return false;
}

static function StaticPrecache(LevelInfo L)
{
    Super.StaticPrecache(L);

    L.AddPrecacheStaticMesh(StaticMesh'ONSDeadVehicles-SM.RAPTORexploded.RaptorWing');
    L.AddPrecacheStaticMesh(StaticMesh'ONSDeadVehicles-SM.RAPTORexploded.RaptorTailWing');
    L.AddPrecacheStaticMesh(StaticMesh'ONSDeadVehicles-SM.RAPTORexploded.RaptorGun');
    L.AddPrecacheStaticMesh(StaticMesh'AW-2004Particles.Debris.Veh_Debris2');
    L.AddPrecacheStaticMesh(StaticMesh'AW-2004Particles.Debris.Veh_Debris1');
    L.AddPrecacheStaticMesh(StaticMesh'WeaponStaticMesh.RocketProj');

    L.AddPrecacheMaterial(Material'AW-2004Particles.Energy.SparkHead');
    L.AddPrecacheMaterial(Material'ExplosionTex.Framed.exp2_frames');
    L.AddPrecacheMaterial(Material'ExplosionTex.Framed.exp1_frames');
    L.AddPrecacheMaterial(Material'ExplosionTex.Framed.we1_frames');
    L.AddPrecacheMaterial(Material'AW-2004Particles.Weapons.SmokePanels2');
    L.AddPrecacheMaterial(Material'AW-2004Particles.Fire.NapalmSpot');
    L.AddPrecacheMaterial(Material'EpicParticles.Fire.SprayFire1');
    L.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.RaptorColorRed');
    L.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.RaptorColorBlue');
    L.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.AttackCraftNoColor');
    L.AddPrecacheMaterial(Material'AW-2004Particles.Weapons.TrailBlura');
    L.AddPrecacheMaterial(Material'Engine.GRADIENT_Fade');
    L.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.raptorCOLORtest');
    L.AddPrecacheMaterial(Material'AW-2004Particles.Fire.SmokeFragment');
}

simulated function UpdatePrecacheStaticMeshes()
{
    Level.AddPrecacheStaticMesh(StaticMesh'ONSDeadVehicles-SM.RAPTORexploded.RaptorWing');
    Level.AddPrecacheStaticMesh(StaticMesh'ONSDeadVehicles-SM.RAPTORexploded.RaptorTailWing');
    Level.AddPrecacheStaticMesh(StaticMesh'ONSDeadVehicles-SM.RAPTORexploded.RaptorGun');
    Level.AddPrecacheStaticMesh(StaticMesh'AW-2004Particles.Debris.Veh_Debris2');
    Level.AddPrecacheStaticMesh(StaticMesh'AW-2004Particles.Debris.Veh_Debris1');
    Level.AddPrecacheStaticMesh(StaticMesh'WeaponStaticMesh.RocketProj');

    Super.UpdatePrecacheStaticMeshes();
}

simulated function UpdatePrecacheMaterials()
{
    Level.AddPrecacheMaterial(Material'AW-2004Particles.Energy.SparkHead');
    Level.AddPrecacheMaterial(Material'ExplosionTex.Framed.exp2_frames');
    Level.AddPrecacheMaterial(Material'ExplosionTex.Framed.exp1_frames');
    Level.AddPrecacheMaterial(Material'ExplosionTex.Framed.we1_frames');
    Level.AddPrecacheMaterial(Material'AW-2004Particles.Weapons.SmokePanels2');
    Level.AddPrecacheMaterial(Material'AW-2004Particles.Fire.NapalmSpot');
    Level.AddPrecacheMaterial(Material'EpicParticles.Fire.SprayFire1');
    Level.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.RaptorColorRed');
    Level.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.RaptorColorBlue');
    Level.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.AttackCraftNoColor');
    Level.AddPrecacheMaterial(Material'AW-2004Particles.Weapons.TrailBlura');
    Level.AddPrecacheMaterial(Material'Engine.GRADIENT_Fade');
    Level.AddPrecacheMaterial(Material'VMVehicles-TX.AttackCraftGroup.raptorCOLORtest');
    Level.AddPrecacheMaterial(Material'AW-2004Particles.Fire.SmokeFragment');

    Super.UpdatePrecacheMaterials();
}

defaultproperties
{
     MaxPitchSpeed=2000.000000
     TrailEffectPositions(0)=(X=-148.000000,Y=-26.000000,Z=51.000000)
     TrailEffectPositions(1)=(X=-148.000000,Y=26.000000,Z=51.000000)
     TrailEffectClass=Class'Onslaught.ONSAttackCraftExhaust'
     StreamerEffectOffset(0)=(X=-219.000000,Y=-35.000000,Z=57.000000)
     StreamerEffectOffset(1)=(X=-219.000000,Y=35.000000,Z=57.000000)
     StreamerEffectOffset(2)=(X=-52.000000,Y=-24.000000,Z=142.000000)
     StreamerEffectOffset(3)=(X=-52.000000,Y=24.000000,Z=142.000000)
     StreamerEffectClass=Class'Onslaught.ONSAttackCraftStreamer'
     StreamerOpacityRamp=(Min=1200.000000,Max=1600.000000)
     StreamerOpacityChangeRate=1.000000
     StreamerOpacityMax=0.700000
     UprightStiffness=500.000000
     UprightDamping=300.000000
     MaxThrustForce=100.000000
     LongDamping=0.050000
     MaxStrafeForce=80.000000
     LatDamping=0.050000
     MaxRiseForce=50.000000
     UpDamping=0.050000
     TurnTorqueFactor=600.000000
     TurnTorqueMax=200.000000
     TurnDamping=50.000000
     MaxYawRate=1.500000
     PitchTorqueFactor=200.000000
     PitchTorqueMax=35.000000
     PitchDamping=20.000000
     RollTorqueTurnFactor=450.000000
     RollTorqueStrafeFactor=50.000000
     RollTorqueMax=50.000000
     RollDamping=30.000000
     StopThreshold=100.000000
     MaxRandForce=3.000000
     RandForceInterval=0.750000
     DriverWeapons(0)=(WeaponClass=Class'Onslaught.ONSAttackCraftGun',WeaponBone="PlasmaGunAttachment")
     RedSkin=Shader'VMVehicles-TX.AttackCraftGroup.AttackCraftChassisFinalRED'
     BlueSkin=Shader'VMVehicles-TX.AttackCraftGroup.AttackCraftChassisFInalBLUE'
     IdleSound=Sound'ONSVehicleSounds-S.AttackCraft.AttackCraftIdle'
     StartUpSound=Sound'ONSVehicleSounds-S.AttackCraft.AttackCraftStartUp'
     ShutDownSound=Sound'ONSVehicleSounds-S.AttackCraft.AttackCraftShutDown'
     StartUpForce="AttackCraftStartUp"
     ShutDownForce="AttackCraftShutDown"
     DestroyedVehicleMesh=StaticMesh'ONSDeadVehicles-SM.AttackCraftDead'
     DestructionEffectClass=Class'Onslaught.ONSVehicleExplosionEffect'
     DisintegrationEffectClass=Class'Onslaught.ONSVehDeathAttackCraft'
     DestructionLinearMomentum=(Min=50000.000000,Max=150000.000000)
     DestructionAngularMomentum=(Min=100.000000,Max=300.000000)
     DamagedEffectOffset=(X=-120.000000,Y=10.000000,Z=65.000000)
     ImpactDamageMult=0.001000
     HeadlightCoronaOffset(0)=(X=76.000000,Y=14.000000,Z=-24.000000)
     HeadlightCoronaOffset(1)=(X=76.000000,Y=-14.000000,Z=-24.000000)
     HeadlightCoronaMaterial=Texture'EpicParticles.Flares.FlashFlare1'
     HeadlightCoronaMaxSize=60.000000
     VehicleMass=4.000000
     bTurnInPlace=Wahr
     bShowDamageOverlay=Wahr
     bDriverHoldsFlag=Falsch
     bCanCarryFlag=Falsch
     ExitPositions(0)=(Y=-165.000000,Z=100.000000)
     ExitPositions(1)=(Y=165.000000,Z=100.000000)
     EntryPosition=(X=-40.000000)
     EntryRadius=210.000000
     TPCamDistance=500.000000
     TPCamLookat=(X=0.000000,Z=0.000000)
     TPCamWorldOffset=(Z=200.000000)
     DriverDamageMult=0.000000
     VehiclePositionString="in a Raptor"
     VehicleNameString="Raptor"
     RanOverDamageType=Class'Onslaught.DamTypeAttackCraftRoadkill'
     CrushedDamageType=Class'Onslaught.DamTypeAttackCraftPancake'
     MaxDesireability=0.600000
     FlagBone="PlasmaGunAttachment"
     FlagOffset=(Z=80.000000)
     FlagRotation=(Yaw=32768)
     HornSounds(0)=Sound'ONSVehicleSounds-S.Horns.Horn03'
     HornSounds(1)=Sound'ONSVehicleSounds-S.Horns.Horn07'
     GroundSpeed=2000.000000
     HealthMax=300.000000
     Health=300
     Mesh=SkeletalMesh'ONSVehicles-A.AttackCraft'
     SoundVolume=160
     CollisionRadius=150.000000
     CollisionHeight=70.000000
     Begin Object Class=KarmaParamsRBFull Name=KParams0
         KInertiaTensor(0)=1.000000
         KInertiaTensor(3)=3.000000
         KInertiaTensor(5)=3.500000
         KCOMOffset=(X=-0.250000)
         KLinearDamping=0.000000
         KAngularDamping=0.000000
         KStartEnabled=Wahr
         bKNonSphericalInertia=Wahr
         KActorGravScale=0.000000
         bHighDetailOnly=Falsch
         bClientOnly=Falsch
         bKDoubleTickRate=Wahr
         bKStayUpright=Wahr
         bKAllowRotate=Wahr
         bDestroyOnWorldPenetrate=Wahr
         bDoSafetime=Wahr
         KFriction=0.500000
         KImpactThreshold=300.000000
     End Object
     KParams=KarmaParamsRBFull'Onslaught.ONSAttackCraft.KParams0'

}