USARBot.FPSLog

///////////////////////////////////////////////////////////
// FPSLog UnrealScript Class created by
// by Marco Zaratti - marco.zaratti@gmail.com
//
//--Abstract-----------------------------------------------
// This class is an Actor placeable in a map that logs
// frame rate in "FPSStats.txt" in /UserLog dir.
// It is useful to trace performance graphs. "FPSStats.txt"
// may be imported in Excel (for instance) where a graph
// can be created in just few mouse clicks.
//---------------------------------------------------------
//
//--How To Use---------------------------------------------
// Just place the Actor FPSLog in your map.
// FPSStats.txt is written when UT Client is closed and its
// output looks like (for each sample):
//
// time, FPS, delta (=1/FPS), counter
//
// time: is the total time passed
// FPS: is the frame rate
// delta: is the the last frame computation time (=1/FPS)
// counter: is e generic counter increased and decreased by
//          triggering or untriggering FPSLog
//
// counter may be used to count the number of robots in the map
// or for any other purpose. To count the number of robots you
// should add some code to your robot class or to KRobot to
// trigger and untrigger FPSLog.
//
// Sample rate may be choosen with maxSamplesSec variable,
// for example:
//   maxSamplesSec=1 mens 1 sample/sec
//   maxSamplesSec=10 means 10 samples/sec
//
// This variable may be specified in the defaultproperties,
// in the FPSLog properties edited in UnrealEd or in *.INI file.
// In *.INI use this syntax:
// [USARBot.FPSLog]
//  maxSamplesSec=10
//
// A final note: UT opens FPSStats.txt in append mode, so
// erase it if you want a new data set.
//---------------------------------------------------------
//
///////////////////////////////////////////////////////////

class FPSLog extends Actor config(USARBot)
    Placeable;

///////////////////////////////////////////////////////////
// FPSLog variables
var FileLog logger;
var() config int maxSamplesSec; //max num of samples/sec
var float maxResolution;
var float timeTotal;
var float timeDelta;
var int tickCounter;

///////////////////////////////////////////////////////////
// Activation variables
enum LogMode{FPS_OFF, FPS_ON, FPS_TRIGGERED}; //possible states
var() config LogMode FPSLogMode; //Used to choose initialstate (needed for USAR.INI)
//used by LoggingTriggered
var bool triggeredLog; //Saves triggered status
var bool markTrigger; //Signals a TRIGGERED notification
var float timeTrigger; //Elapsed time between triggers

///////////////////////////////////////////////////////////
// Other variables
var int eventCounter;  //eache Trigger increases counter
                       //eache UnTrigger decreases counter

///////////////////////////////////////////////////////////
simulated function PostNetBeginPlay()
{
    Super.PostNetBeginPlay();

    maxResolution = 1.0/maxSamplesSec;
    timeTotal = 0.0;
    timeDelta = 0.0;
    tickCounter = 0;
    eventCounter = 0;
    triggeredLog=False;
    markTrigger=False;
    timeTrigger= 0.0;

    logger = Spawn(class'FileLog');
    //Open FPS log file (will be placed in /UserLog):
    logger.OpenLog("FPSStats","txt");
}

simulated event SetInitialState()
{
    //We need FPSLogMode var if we want to set the state from USAR.INI
    switch(FPSLogMode)
    {
        case FPS_OFF:
            InitialState='LoggingOff';break;
        case FPS_ON:
            InitialState='LoggingOn';break;
        case FPS_TRIGGERED:
            InitialState='LoggingTriggered';break;
        default:
            InitialState='LoggingOff';break;
    }
    super.SetInitialState();
}

simulated event Destroyed()
{
    logger.CloseLog();
    //Close FPS log file:
    Super.Destroyed();
}

event Trigger( Actor Other, Pawn EventInstigator )
{
    eventCounter++;
}

event UnTrigger( Actor Other, Pawn EventInstigator )
{
    eventCounter--;
    if(eventCounter < 0)
        eventCounter = 0;
}

//+++++++++++++++++++++ STATE +++++++++++++++++++++++++++//
// Log always
state LoggingOn
{
    simulated function Tick(float Delta)
    {
        local float fpsStat;
        local string outStr;

        Super.Tick(Delta);

        tickCounter++;
        timeTotal += Delta;
        timeDelta += Delta;

        if(timeDelta >= maxResolution)
        {
            fpsStat = tickCounter / timeDelta;
            timeDelta = (timeDelta / tickCounter)*1000;
            outStr = timeTotal $","$ fpsStat $","$ timeDelta $","$ eventCounter;
            logger.LogF(outStr);
            tickCounter = 0;
            timeDelta = 0.0;
        }
    }
}

//+++++++++++++++++++++ STATE +++++++++++++++++++++++++++//
// Do not log
state LoggingOff
{
    ignores Trigger, UnTrigger;
}

//+++++++++++++++++++++ state +++++++++++++++++++++++++++//
// Log only when eventCounter > 0
state LoggingTriggered
{
    simulated function Tick(float Delta)
    {
        local float fpsStat;
        local string outStr;

        Super.Tick(Delta);

        if(triggeredLog)
        {
            if(eventCounter == 0)
            {
                triggeredLog = false;
                timeTrigger += timeDelta;
                tickCounter = 0;
                timeDelta = 0.0;
            }
        }
        else
        {
            timeTrigger += Delta;
            if(eventCounter > 0)
            {
                triggeredLog = true;
                markTrigger = true; //ADDS "TRIGGERED" to output sample
            }
        }

        if(triggeredLog)
        {
            tickCounter++;
            timeTotal += Delta;
            timeDelta += Delta;

            if(timeDelta >= maxResolution)
            {
                fpsStat = tickCounter / timeDelta;
                timeDelta = (timeDelta / tickCounter)*1000;
                outStr = timeTotal $","$ fpsStat $","$ timeDelta $","$ eventCounter;
                if(markTrigger)
                {
                    outStr $= ",+"$ timeTrigger $",TRIGGERED";
                    markTrigger = false;
                }
                logger.LogF(outStr);
                tickCounter = 0;
                timeDelta = 0.0;
            }
        }
    }
}

defaultproperties
{
    FPSLogMode=FPS_ON
    maxSamplesSec=2
    bHidden=True
    Texture=Texture'Engine.S_Note'
}