USARBot.GasSensor

// ===============================================================
// USARBot.GasSensor
// ===============================================================

class GasSensor extends sensor config(USARBot);

var config String GasType;
var config Range ValidRange; // the detecting range in percent
var config float Resoluation; // in percent
var array<GasSource> gasSources;

function Init(String SName, Actor parent, vector position, rotator direction, KVehicle platform, name mount)
{
    local int i, j;
    local AmbientSource s;
    
    Super.Init(SName,parent,position,direction,platform,mount);
    
    j = 0;
    for (i=0; i<USARDeathMatch(Level.Game).Sources.length; i++) {
        s = USARDeathMatch(Level.Game).Sources[i];
        if (s.IsA('GasSource') && s.isType(GasType)) {
            gasSources[i] = GasSource(s);
            j += 1;
        }
    }
}

function ConvertParam(USARConverter converter)
{
}

function String GetData()
{
    local string Outstring;
    local int i;
    local float dens;
    
    dens = 0;
    for (i = 0; i < gasSources.length; i++) 
        dens = Max(dens,gasSources[i].getDensity(Location));
    
    dens += RandRange(-Noise,Noise)*dens;
    dens = int(InterpCurveEval(OutputCurve, dens)/Resoluation)*Resoluation;

    if (dens<ValidRange.Min) 
        dens = ValidRange.Min;
    else if (dens>ValidRange.Max) 
        dens = ValidRange.Max;
            
    Outstring = "{Name "$ItemName$"} {Gas "$GasType$"} {Density "$dens$"}";

    return Outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring @ "{Gas " $ GasType$"}" @
                "{Resoluation " $ Resoluation $ "}" @
                "{Range " $ ValidRange.Min $ "," $ ValidRange.Max $ "}";
    return outstring;
}

defaultproperties
{
     ItemType="GasSensor"
     // Detecting range 0~100%
     ValidRange=(Min=0,Max=100)
     GasType="CO2"
     OutputCurve=(Points=((InVal=0,OutVal=0),(InVal=100,OutVal=100)))
}