USARBot.ERSpaw

///////////////////////////////////////////////////////////////////////////
// Simple Touch sensor for AIBO paws based on RangeSensor
// Mapping:
// Contact = true  if (0 < range <= MaxRange)
// Contact = false if (range > MaxRange)
//
// by Marco Zaratti - marco.zaratti@gmail.com
///////////////////////////////////////////////////////////////////////////

class ERSpaw extends RangeSensor config (USARBot);

function ConvertParam(USARConverter converter)
{
    if (converter!=NONE) {
        uuMaxRange = converter.LengthToUU(MaxRange);
        uuMinRange = converter.LengthToUU(MinRange);
    }
    else {
        uuMaxRange = MaxRange;
        uuMinRange = MinRange;
    }
}

function float GetRange()
{
    local vector HitLocation,HitNormal;
    local float range;

    if (Trace(HitLocation, HitNormal, Location + uuMaxRange*vector(curRot), Location, true)==NONE)
        return 0;
    else
    {
        range = VSize(HitLocation-Location);
        if (converter!=None)
            range=converter.LengthFromUU(range);
    }

    if (range <= MaxRange)
        return 1;

    return 0;
}

function String GetData()
{
    local string outstring;
    curRot=Rotation;
    if(GetRange() > 0)
        outstring="{Name "$ItemName$" Touch true}";
    else
        outstring="{Name "$ItemName$" Touch false}";
    return outstring;
}

defaultproperties
{
    bUseGroup=True
    ItemType="Touch"
    MaxRange=0.0248 //2.48cm
    MinRange=0
}