USARBot.HumanMotionSensor

class HumanMotionSensor extends Sensor config (USARBot);

var config float MaxRange;
var config float FOV;
var float MaxSpeed;

var float uuMaxRange;
var float uuMaxSpeed;

function ConvertParam(USARConverter converter)
{
    if (converter!=None) {
        uuMaxRange = converter.LengthToUU(MaxRange);
        uuMaxSpeed = converter.SpeedToUU(MaxSpeed);
    } else {
        uuMaxRange = MaxRange;
        uuMaxSpeed = MaxSpeed;
    }
}

function String GetData()
{
    local string Outstring;
    local vector SegLoc,SegVel,HitLocation,HitNormal;
    local float CosAngle,Distance,Speed,Prob;
    local array<USARVictim> Victims;
    local int i,j;
    local actor a;

    Outstring="";
    Victims = USARDeathMatch(Level.Game).Victims;
    for (i=0;i<Victims.length;i++) {
        for (j=0;j<8;j++) {
            // static segment
            SegVel = Victims[i].getSegmentVel(j);
            if (SegVel.X==0 && SegVel.Y==0 && SegVel.Z==0) Continue;
            // not in valid range
            SegLoc = Victims[i].getSegmentLocation(j);
            Distance = VSize(SegLoc-Location);
            if (Distance>uuMaxRange) continue;
            // not in FOV
            CosAngle = ((SegLoc - Location) dot vector(Rotation)) / Distance; // VSize(vector(Rotation))=1;
            if (CosAngle<Cos(FOV/2.0)) Continue; // FOV/2
            // no obstacles between the sensor and the victim
            a = Trace(HitLocation, HitNormal, SegLoc, Location, true);
            if (a!=None && a!=Victims[i]) Continue;
            // get moving speed
            Speed = SegVel dot vector(Rotation);
            Speed = Sqrt((SegVel.X*SegVel.X+SegVel.Y*SegVel.Y+SegVel.Z*SegVel.Z) - Speed*Speed);
            if (Speed>uuMaxSpeed) Speed=uuMaxSpeed;
            Prob=(1.0-Distance/uuMaxRange)*(Speed/uuMaxSpeed)*CosAngle;
            Outstring="{Prob "$converter.FloatString(Prob)$"}";
            break;
        }
        if (Speed>0) break;
    }
    if (Outstring!="") Outstring = super.GetData()@OutString;
    return Outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring@"{MaxRange "$converter.FloatString(MaxRange)$"} {Fov "$converter.FloatString(FOV)$"}";
    return outstring;
}

defaultproperties
{
    ItemType="HumanMotion"
    MaxRange=3 // 3 meter
    MaxSpeed=0.5 // 5 cm/s
    FOV=1.0472 // 60 deg
    OutputCurve=(Points=((InVal=0,OutVal=0),(InVal=1000,OutVal=1000)))
}