USARBot.IR2Sensor

// Based on Erik Winter IRSensor class
//
// This class modifies the way noise is handled. It allows to shape noise
// in any way with an InterpCurve.
// Note: Noise shaped this way is no more linear but parabolic
//
// by Marco Zaratti - marco.zaratti@gmail.com
//==============================================================================
//
// This class is basically the same as the USARSim RangeSensor class
// For the moment only the Range and output curve parameters are changed
//	author: Erik Winter
//  created: 2005-02-24	Created the class from the USARSim RangeSensor class
//
//  modified:	2005-03-07	Made the IR look straight through transparent materials
//				2005-03-15  If the IR hits a transparent material it now sends out a new trace from the HitLocation recursively
//							until it hits a non-transparent material or reaches MaxRange
//
//	Todo:
//		- Apply the fact that the IR can see through, and though miss glass walls
//			* halfly done, if it hits a transparent material it returns maxRange. On these maps it should be an okay simplification, Fully Done

class IR2Sensor extends RangeSensor config (USARBot);

var config InterpCurve  OutputNoise;

function float GetRange()
{
    local vector HitLocation, HitNormal;
    local vector curLoc, direction;
    local float range, error;
    local material mtrl;


    range=0;
    curLoc=Location;
    direction = vector(Rotation);

    while(range < uuMaxRange)
    {
        if (Trace(HitLocation, HitNormal, Location + uuMaxRange*direction, curLoc, true, vect(0,0,0), mtrl)==NONE){
            range=MaxRange;
            break;
        }
        else {
            range=VSize(HitLocation-Location);
            if (converter!=None)
                range=converter.LengthFromUU(range);
        }

        if(InStr(string(mtrl), "Trans")==-1) // The IR hitted a non-transparent material.
            break;
        else
        {
            curLoc = HitLocation + 0.1*direction;
            range = VSize(curLoc - Location);
        }
    }
    //Cap range
    if (range>MaxRange) range=MaxRange;
    if (range<MinRange) range=MinRange;

    //Add noise
    if (OutputCurve.Points.length>0)
    {
        range=InterpCurveEval(OutputCurve, range);
        error=InterpCurveEval(OutputNoise, range);
    }
    range += RandRange(-error,error)*range;

    //Cap range again
    if (range>MaxRange) range=MaxRange;
    if (range<MinRange) range=MinRange;



    return range;

}

function String GetData()
{
    local string outstring;
    outstring="{Name "$ItemName$" Range "$converter.FloatString(GetRange())$"}";
    return outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring@"{MaxRange "$converter.FloatString(MaxRange)$"} {MinRange "$converter.FloatString(MinRange)$"}";
    return outstring;
}

defaultproperties
{
    bUseGroup=True
    ItemType="IR"
    HiddenSensor=false
    MaxRange=.8 // 0.80 m
    MinRange=.1 // 0.10 m
    OutputCurve=(Points=((InVal=0.000000,OutVal=0.000000),(InVal=0.800000,OutVal=0.800000)))
    OutputNoise=(Points=((InVal=0.0,OutVal=0.0),(InVal=0.8,OutVal=0.1)))
}