USARBot.IRCamera

class IRCamera extends IRSensor config (USARBot);

var config int Fov;
var config int HorResolution;
var config int VerResolution;
var config int RowsAtTime;

var int uuFov, uuHorResolution, uuVerResolution;

var string rangeData[240];  //max width = 240
var USARRemoteBot rBot;

var int rowCount;   //counter used to send each time a different row
var bool bScan;

simulated function PostNetBeginPlay()
{
    local int i;
    Super.PostNetBeginPlay();
    rowCount=0;
    for (i=0; i<240; i++)
        rangeData[i]="";
    if (VerResolution>240)
        VerResolution = 240;
}


function ConvertParam(USARConverter converter)
{
    if (converter!=None) {
        uuFov = converter.AngleToUU(Fov);
        uuHorResolution = converter.AngleToUU(HorResolution);
        uuVerResolution = converter.AngleToUU(VerResolution);
    } else {
        uuFov = Fov;
        uuHorResolution = HorResolution;
        uuVerResolution = VerResolution;
    }
}

function string Set(String opcode, String args)
{
    if(Caps(opcode)=="SCAN") {
        bScan = true;
        return "OK";
    }
    return "Failed";
}

function String GetData()
{
    local string outstring;
    local int i, j;
    local int range;

    if (!bScan) return "";
    
    outstring = "{Name "$ItemName$"} {Time "$Level.TimeSeconds$"} ";

    curRot = base.Rotation + myDirection;
    for (i=0; i<RowsAtTime; i++) { //we want to send X rows atime (and have bandwith)

        rangeData[rowCount]="";
        curRot.Pitch = Rotation.Pitch + (uuFov/2 - rowCount*uuFov/uuVerResolution);

        for (j=-uuFov/2; j<uuFov/2; j+= uuFov/uuHorResolution)
        {
            curRot.Yaw = Rotation.Yaw + j;
            range = GetRange() ;        //We get it as int to save space
            if (rangeData[rowCount] == "")
                rangeData[rowCount] = converter.FloatString(range);
            else
                rangeData[rowCount] = rangeData[rowCount]$","$converter.FloatString(range);
        }
        outstring = outstring$"{Row "$rowCount$" Range "$rangeData[rowCount]$"} ";
        rowCount++;

        if (rowCount >= uuFov/uuVerResolution) {
            rowCount = 0;
            if (rBot == None)
                rBot = USARRemoteBot(Platform.Controller);
            rBot.IRCameraScan = false; //reset command
        }
    }
    bScan = false;
    return outstring;
}    

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring@"{Fov "$converter.FloatString(Fov)$"}";
    outstring = outstring@"{HorResolution "$converter.FloatString(HorResolution)$"} {VerResolution "$converter.FloatString(VerResolution)$"}";
    return outstring;
}

defaultproperties
{
    HiddenSensor=true
    DrawScale=1.0
    StaticMesh=StaticMesh'USARSim_VehicleParts_Meshes.Sensors.LMS200'
    bHardAttach=true
    ItemType="IRCamera"
    MaxRange=4.0
    MinRange=0.04
    Fov=0.6981 // 40 deg
    HorResolution=0.01534 // 160 uu
    VerResolution=0.01150 // 120 uu
    OutputCurve=(Points=((InVal=0,OutVal=0),(InVal=4.0,OutVal=4.0)))
    RowsAtTime=5
}