USARBot.IRScanner

class IRScanner extends IRSensor config (USARBot);

var config float ScanInterval;
var config float Resolution;
var config float ScanFov;
var config bool bYaw;
var config bool bPitch;

var int uuResolution, uuScanFov;

var string rangeData;
var float time;
var USARRemoteBot rBot;

simulated function PostNetBeginPlay()
{
    Super.PostNetBeginPlay();
    rangeData="";
    if (ScanInterval>=0.1)
        SetTimer(ScanInterval,true);
}

function ConvertParam(USARConverter converter)
{
    super.ConvertParam(converter);

    if (converter!=None) {
        uuResolution = converter.AngleToUU(Resolution);
        uuScanFov = converter.AngleToUU(ScanFov);
    } else {
        uuResolution = Resolution;
        uuScanFov = ScanFov;
    }
}

function timer()
{
    local int i;
    local float range;
    local rotator turn;

    time = Level.TimeSeconds;
    rangeData="";
    for (i=uuScanFov/2;i>-uuScanFov/2;i-=uuResolution)
    {
        if (bYaw)
            turn.Yaw = i;
        if (bPitch)
            turn.Pitch = i;
        curRot = rTurn(Rotation,turn);
        range = GetRange();
        if (rangeData == "") rangeData = converter.FloatString(range);
        else rangeData = rangeData$","$converter.FloatString(range);
        //log("i="$i@"rot="$rot@"Rotation="$Rotation@"range="$range);
    }
}

function rotator rTurn(rotator rHeading,rotator rTurnAngle)
{
    // Generate a turn in object coordinates
    //     this should handle any gymbal lock issues

    local vector vForward,vRight,vUpward;
    local vector vForward2,vRight2,vUpward2;
    local rotator T;
    local vector  V;

    GetAxes(rHeading,vForward,vRight,vUpward);
    //  rotate in plane that contains vForward&vRight
    T.Yaw=rTurnAngle.Yaw; V=vector(T);
    vForward2=V.X*vForward + V.Y*vRight;
    vRight2=V.X*vRight - V.Y*vForward;
    vUpward2=vUpward;

    // rotate in plane that contains vForward&vUpward
    T.Yaw=rTurnAngle.Pitch; V=vector(T);
    vForward=V.X*vForward2 + V.Y*vUpward2;
    vRight=vRight2;
    vUpward=V.X*vUpward2 - V.Y*vForward2;

    // rotate in plane that contains vUpward&vRight
    T.Yaw=rTurnAngle.Roll; V=vector(T);
    vForward2=vForward;
    vRight2=V.X*vRight + V.Y*vUpward;
    vUpward2=V.X*vUpward - V.Y*vRight;

    T=OrthoRotation(vForward2,vRight2,vUpward2);

   return(T);
}

function string Set(String opcode, String args)
{
    if (Caps(opcode)=="SCAN") {
        timer();
        return "OK";
    }
    return "Failed";
}

function String GetHead()
{
    local string outstring;

    if (bWithTimeStamp)
        outstring="SEN {Time "$time$"} {Type "$ItemType$"}";
    else
        outstring="SEN {Type "$ItemType$"}";

    return outstring;
}
function String GetData()
{
    local string outstring;

    if (rangeData == "") return "";

    outstring =  "{Name "$ItemName$"} "
                //$"{Time "$time$"} "
                //$"{Location "$Location$"} "
                //$"{Rotation "$(base.Rotation + myDirection)$"} "
                $"{Resolution "$converter.FloatString(Resolution)$"} "
                $"{FOV "$converter.FloatString(ScanFov)$"} "
                $"{Range "$rangeData$"}";
    rangeData = "";

    return outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring@"{Resolution "$converter.FloatString(Resolution)$"} {Fov "$converter.FloatString(ScanFov)$"}";
    outstring = outstring@"{Paning "$bYaw$"} {Tilting "$bPitch$"}";
    return outstring;
}

defaultproperties
{
    bHardAttach=true
    ItemType="IRScanner"
    MaxRange=20
    MinRange=0.1
    ScanInterval=0.0
    Resolution==0.01745
    ScanFov=3.1415
    bYaw=false
    bPitch=false
    OutputCurve=(Points=((InVal=0,OutVal=0),(InVal=1000,OutVal=1000)))
}