USARBot.RangeScanner3D

// ===============================================================
// USARBot.RangeScanner3D
//
// Created by UClasses - (C) 2000-2001 by meltdown@thirdtower.com
// Original developed by Dapeng Zhange
// Modified by Jijun Wang 02/23/2006
// ===============================================================

class RangeScanner3D extends RangeScanner;

var config float VerticalFOV;
var config float HorizontalFOV;
var config float VerticalResolution;
var config float HorizontalResolution;

var bool bScannerStarted;
var int uuVerFOV;
var int uuHorFOV;
var int uuVerStep;
var int uuHorStep;

function ConvertParam(USARConverter converter)
{
    super.ConvertParam(converter);

    if (converter!=None) {
        uuVerFov  = converter.AngleToUU(VerticalFOV);
        uuHorFov  = converter.AngleToUU(HorizontalFOV);
        uuVerStep = converter.AngleToUU(VerticalResolution);
        uuHorStep = converter.AngleToUU(HorizontalResolution);
    } else {
        uuVerFov  = VerticalFOV;
        uuHorFov  = HorizontalFOV;
        uuVerStep = VerticalResolution;
        uuHorStep = HorizontalResolution;
    }
}

function timer()
{
    local int i,j;
    local float range;
    local rotator turn;

    time = Level.TimeSeconds;
    rangeData="";
    //from bottom to top
    for (i=-uuVerFov/2;i<uuVerFov/2;i+=uuVerStep)
        //from left to right
        for (j=-uuHorFov/2;j<uuHorFov/2;j+=uuHorStep) {
            turn.Yaw = j;
            turn.Pitch = i;
            curRot = rTurn(Rotation,turn);
            range = GetRange();
            if (rangeData == "") rangeData = converter.FloatString(range);
            else rangeData = rangeData$","$converter.FloatString(range);
        }
}

function String GetData()
{
    local string outstring;

    if (rangeData == "") return "";

    outstring =  "{Name "$ItemName$"} "
                //$"{Time "$time$"} "
                //$"{Location "$Location$"} "
                //$"{Rotation "$(base.Rotation + myDirection)$"} "
                $"{Resolution "$converter.FloatString(VerticalResolution)$","$converter.FloatString(HorizontalResolution)$"} "
                $"{FOV "$converter.FloatString(VerticalFOV)$","$converter.FloatString(HorizontalFOV)$"} "
                $"{Range "$rangeData$"}";
    rangeData = "";

    return outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = "{Name "$ItemName$"}"@
                "{MaxRange "$converter.FloatString(MaxRange)$"}"@
                "{MinRange "$converter.FloatString(MinRange)$"}"@
                "{VerticalResolution "$converter.FloatString(VerticalResolution)$"}"@
                "{HorizontalResolution "$converter.FloatString(HorizontalResolution)$"}"@
                "{VerticalFOV "$converter.FloatString(VerticalFOV)$"}"@
                "{HorizontalFOV "$converter.FloatString(HorizontalFOV)$"}";
    return outstring;
}

defaultproperties
{
     ScanInterval=0.500000
     VerticalFOV=0.8029 // 46.000000 degree
     HorizontalFOV=0.7505 // 43.000000 degree
     VerticalResolution=0.04014 // 20 pixels
     HorizontalResolution=0.05 // 15 pixels
     ItemType="3DRangeScanner"
}