USARBot.RangeSensor

class RangeSensor extends Sensor config (USARBot) abstract;

var config float MaxRange,MinRange;
var Rotator curRot;
var float uuMaxRange,uuMinRange;

function ConvertParam(USARConverter converter)
{
    if (converter!=NONE) {
        uuMaxRange = converter.LengthToUU(MaxRange);
        uuMinRange = converter.LengthToUU(MinRange);
    }
    else {
        uuMaxRange = MaxRange;
        uuMinRange = MinRange;
    }
}

// get range data in Meter
function float GetRange()
{
    local vector HitLocation,HitNormal;
    local float range;

    if (Trace(HitLocation, HitNormal, Location + uuMaxRange*vector(curRot), Location, true)==NONE) range=MaxRange;
    else {
        range=VSize(HitLocation-Location);
        if (converter!=None)
            range=converter.LengthFromUU(range);
    }
    if (OutputCurve.Points.length>0)
        range=InterpCurveEval(OutputCurve, range);
    range += RandRange(-Noise,Noise)*range;
    if (range>MaxRange) range=MaxRange;
    if (range<MinRange) range=MinRange;
    return range;
}

function String GetData()
{
    local string outstring;
    curRot=Rotation;
    outstring="{Name "$ItemName$" Range "$converter.FloatString(GetRange())$"}";
    return outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring@"{MaxRange "$converter.FloatString(MaxRange)$"} {MinRange "$converter.FloatString(MinRange)$"}";
    return outstring;
}

defaultproperties
{
    ItemType="Range"
    MaxRange=3 // 3 meter
    MinRange=0.1 // 0.1 meter
    OutputCurve=(Points=((InVal=0,OutVal=0),(InVal=1000,OutVal=1000)))
    uuMaxRange=0.0
}