USARBot.SoundSensor

class SoundSensor extends Sensor config (USARBot);

function String GetData()
{
    local string Outstring;
    local float Distance,tmpLoudness,tmpDuration;
    local float Loudness,Duration;
    local array<USARVictim> Victims;
    local int i;

    Outstring="";
    Victims = USARDeathMatch(Level.Game).Victims;
    for (i=0;i<Victims.length;i++) {
        // no sound
        if (Victims[i].HelpSound==None) Continue;
        // not in sound radius
        Distance = VSize(Victims[i].Location-Location);
        if (Distance>Victims[i].SoundRadius*100) Continue;
        // get loudness
        Distance = Distance/Victims[i].SoundRadius/50;
        if (Distance<1) 
            tmpLoudness=Victims[i].SoundVolume;
        else            
            tmpLoudness = Victims[i].SoundVolume / (Distance*Distance);
        // get duration
        tmpDuration = GetSoundDuration(Victims[i].HelpSound);
        // find the loudest sound
        if (Loudness<tmpLoudness) {
            Loudness = tmpLoudness;
            Duration = tmpDuration;
        }
    }
    Loudness += RandRange(-Noise,Noise)*Loudness;
    Duration += RandRange(-Noise,Noise)*Duration;
    if (Loudness>0)
        Outstring=super.GetData()@"{Loudness "$converter.FloatString(Loudness)$"} {Duration "$converter.FloatString(Duration)$"}";
        
    return Outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    return outstring;
}

defaultproperties
{
    ItemType="Sound"
    OutputCurve=(Points=((InVal=0,OutVal=0),(InVal=1000,OutVal=1000)))
}