USARBot.StereoP2AT

class StereoP2AT extends P2AT;

var config vector stereoSpacing; //(eye to eye)/2 spacing in UU
var vector uuStereoSpacing;

simulated function ConvertParam(USARConverter converter)
{
    Super.ConvertParam(converter);
    
    if (converter!=None) {
        uuStereoSpacing = converter.LengthVectorToUU(stereoSpacing);
    } else {
        uuStereoSpacing = stereoSpacing;
    }
}

simulated function DrawHud(Canvas C)
{
    local int halfSizeX;
    local vector stereoRotated;

    halfSizeX = C.SizeX/2.0;
    stereoRotated =  uuStereoSpacing >> myCamera.Rotation;
    
    C.Reset();
    C.Clear();  //Clears frame & Z buffers
    
    //left Eye:
    C.DrawPortal(0, 0, halfSizeX, C.SizeY, myCamera, myCamera.Location - stereoRotated, myCamera.Rotation, CameraZoom);
    
    //Right Eye:
    C.DrawPortal(halfSizeX, 0, halfSizeX, C.SizeY, myCamera, myCamera.Location + stereoRotated, myCamera.Rotation, CameraZoom);

    super.DrawHud(C);
}

defaultproperties
{
    stereoSpacing=(Y=0.04) //4 cm: (eye to eye)/2 spacing in meter
}