USARBot.TeleMax

//===============================================
// The following command will put the arm in initial pose;
// MISPKG {Name TeleMaxArm} {Link1 0} {Link2 2} {Link3 0} {Link4 -2} {Link5 0} {Link6 0} {Link7 0}
//===============================================

class TeleMax extends SkidSteeredRobot config(USARBot);

var config bool bMultiView;

simulated function DrawHud(Canvas C)
{
    local int halfX, halfY;

    if (!bMultiView || Cameras.length<4) {
        Super.DrawHud(C);
        return;
    }

    C.Reset();
    C.Clear();  //Clears frame & Z buffers
    halfX = C.SizeX/2;
    halfY = C.SizeY/2;
    C.DrawPortal(    0,     0, halfX, halfY, CamList[0], CamList[0].Location, CamList[0].Rotation, CamList[0].CameraFov);
    C.DrawPortal(halfX,     0, halfX, halfY, CamList[1], CamList[1].Location, CamList[1].Rotation, CamList[1].CameraFov);
    C.DrawPortal(    0, halfY, halfX, halfY, CamList[2], CamList[2].Location, CamList[2].Rotation, CamList[2].CameraFov);
    C.DrawPortal(halfX, halfY, halfX, halfY, CamList[3], CamList[3].Location, CamList[3].Rotation, CamList[3].CameraFov);

    super.DrawHud(C);
}

defaultproperties
{
  //---Wheel/Track information.  Since the Talon has two tracks that behave like two skid-steered wheels, we have two of these definitions
  // The next two definitions will create a skid steered Talon

    // Number=0 indicates that this track is the first JointPart defined in USARBot.ini (ORDER MATTERS!)
    // Power=Right_Powered tells USARSim to spin the track's wheels using the right throttle
    // Note that since the variables SteerType and MaxSteerAngle are not defined, the track's wheels are not steered
    Wheels(0)=(Number=0,PowerType=Right_Powered);

    // Number=1 indicates that this track is the second JointPart defined in USARBot.ini (ORDER MATTERS!)
    // Power=Left_Powered tells USARSim to spin the track's wheels using the left throttle
    // Note that since the variables SteerType and MaxSteerAngle are not defined, this track's wheels are not steered
    Wheels(1)=(Number=1,PowerType=Left_Powered);
  //---

  //--Other Robot's Properties
    StaticMesh=StaticMesh'USARSim_Vehicles_Meshes.Talon.TalonBody'
    DrawScale=4.762
    bMultiView=False
    TireRollFriction=25.000000
    TireLateralFriction=25.00000
    TireSlipRate=0.0003000
    TireSoftness=0.000000

    // Configuration Parameters. Note: these variables need to be correspond to your robot's model.
    Dimensions=(X=0.9117,Y=0.5903,Z=0.3654) // X=Length=0.9117m, Y=Width=0.5903m, Z=Height=0.3654m
    maxSpinSpeed=3.1416                     // Maximum track's spin speed is 3.1416 rad/sec = 180 deg/sec

    Begin Object Class=KarmaParamsRBFull Name=KParams0
        KInertiaTensor(0)=0.010000
        KInertiaTensor(3)=0.02000
        KInertiaTensor(5)=0.03000
        KCOMOffset=(X=0.000000,Z=-1.000000)
        KLinearDamping=0.500000
        KAngularDamping=50.00000
        KStartEnabled=True
        bHighDetailOnly=False
        bClientOnly=False
        bKDoubleTickRate=True
        KFriction=0.600000
        Name="KParams0"
    End Object
    KParams=KarmaParamsRBFull'USARBot.TeleMax.KParams0'
  //--
}