USARBot.TouchSensor

class TouchSensor extends Sensor config (USARBot);

const TouchRange = 0.16; // 3mm
const ScanStep = 0.25; // 4.7mm
const PointsPerCircle = 6;

var config float Diameter;
var config bool bDebug;
var float uuRadius;
var int nCircles;
var float CircleStep;

function ConvertParam(USARConverter converter)
{
    if (converter!=NONE) {
        uuRadius = converter.LengthToUU(Diameter)/2;
    }
    else {
        uuRadius = Diameter/2;
    }
    nCircles = int(uuRadius/ScanStep)+1;
    CircleStep = 2*pi/PointsPerCircle;
}

function bool isTouch()
{
    local vector HitLocation, HitNormal;
    local actor Bumper;
    local vector RotX, RotY, RotZ;
    local rotator curRot;
    local vector startVec;
    local float radius;
    local int i, j; 

    curRot = Rotation;
    startVec = Location;
    GetAxes(Rotation, RotX, RotY, RotZ);
    
    // send one Trace straight ahead
    Bumper = Trace(HitLocation, HitNormal, startVec + touchRange * vector(curRot), startVec, true);
    if (Bumper != NONE) {
        if (bDebug) log("Bump with "$Bumper);
        return true;
    }
    
    // detect along the circle from the edge to the center with step ScanStep;
    for (i = 0; i < nCircles; i++) {
        radius = (nCircles - i) * ScanStep;
        for (j = 0; j < PointsPerCircle; j++) {
            startVec = Location + uuRadius * cos(j * CircleStep) * RotY + uuRadius * sin(j * CircleStep) * RotZ;
            Bumper = Trace(HitLocation, HitNormal, startVec + touchRange * vector(curRot), startVec, true);
            if (Bumper != NONE) {
                if (bDebug) log("Bump with "$Bumper);
                return true;
            }
        }
    }
    
    return false;
}

function String GetData()
{
    local string outstring;
    outstring="{Name "$ItemName$" Touch "$isTouch()$"}";
    return outstring;
}

function String GetConfData()
{
    local string outstring;
    outstring = Super.GetConfData();
    outstring = outstring@"{Diameter "$converter.FloatString(Diameter)$"}";
    return outstring;
}

defaultproperties
{
//Scaled with 4.762 at Mon Sep 25 14:21:52 EDT 2006
    bUseGroup=True
    ItemType="Touch"
    HiddenSensor=true
    DrawScale3D=(X=0.1)
    Diameter=0.01 // 1 cm
    drawscale=0.4762
}