USARBotAPI.icu_mut

class icu_mut extends Mutator;

var bool bAffectSpectators; // If this is set to true, an interaction will be created for spectators
var bool bAffectPlayers; // If this is set to true, an interaction will be created for players
var bool bHasInteraction;
var bool bDrawEnemy;
var bool bDrawFriendly;

function PreBeginPlay()
{
    Log("ICU Mutator Started"); // Always comment out your logs unless they're errors
}

simulated function Tick(float DeltaTime)
{
    local PlayerController PC;

    // If the player has an interaction already, exit function.
    if (bHasInteraction)
        Return;
        // DynamicActors is not very fast, so it's used only when really necessary. Using it once is no big deal.
    ForEach DynamicActors(Class'PlayerController', PC)
    {
        if (Viewport(PC.Player) != None) // Find the local Player
        {
            // Run a check to see whether this mutator should create an interaction for the player
            if ((PC.PlayerReplicationInfo.bIsSpectator &&  bAffectSpectators) || (bAffectPlayers && !PC.PlayerReplicationInfo.bIsSpectator))
            {
                PC.Player.InteractionMaster.AddInteraction("USARBotAPI.MyInteraction", PC.Player); // Create the interaction
                bHasInteraction = True; // Set the variable so this lot isn't called again
                Return; // Exit function, and therefore exit the foreach iteration
        }
        }
    }
}

DefaultProperties
{
     bAffectSpectators=true
     bAffectPlayers=true
     RemoteRole=ROLE_SimulatedProxy
     bAlwaysRelevant=true
}