USARBotAPI.BotDeathMatch

class BotDeathMatch extends DeathMatch
    config(USARBotAPI);

var class<VizServer>    VizServerClass;
var VizServer           theVizServer;
var class<BotServer>    BotServerClass;
var BotServer           theBotServer;
var bool                bServerLoaded;
var class<RemoteBotInfo> RemoteBotConfigClass;
var class<RemoteBot>    RemoteBotClass;
var RemoteBotInfo       RemoteBotConfig;
var int                 NumRemoteBots;
var ComServer           theComServer;
var class<ComServer>    ComServerClass;


function PostBeginPlay()
{
    Super.PostBeginPlay();

    if(!bServerLoaded)
    {
        theVizServer = spawn(VizServerClass, self);
        theVizServer.gameClass = "BotDeathMatch";
        
        theBotServer = spawn(BotServerClass);
        theBotServer.gameClass = "BotDeathMatch";
        
        theComServer = spawn(ComServerClass,self);
        theComServer.gameClass = "BotDeathMatch";
        
        bServerLoaded = true;
    }
    RemoteBotConfig = spawn(RemoteBotConfigClass);
}

function RemoteBot AddRemoteBot(BotConnection theConnection, string clientName, int teamNum, vector startLocation, rotator startRotation, string className)
{
    local RemoteBot NewBot;
    local NavigationPoint startSpot;

    startSpot = FindPlayerStart(NewBot);

    newBot = Spawn(RemoteBotClass, self, ,startLocation, startRotation);

    newBot.bIsPlayer = true;
    newBot.bHidden = false;
    if ( NewBot != None ) {
        NewBot.myConnection = theConnection;
        NewBot.as = theConnection.as;
        NewBot.ae = theConnection.ae;
        NewBot.ib = theConnection.ib;
        NewBot.PlayerReplicationInfo.PlayerID = CurrentID++;
        NumRemoteBots++;
        NumPlayers++;
        if(clientName == "") {
            newBot.PlayerReplicationInfo.PlayerName = "Unnamed_Bot_" $ NumRemoteBots;
        } else {
            newBot.PlayerReplicationInfo.PlayerName = clientName;
        }

        if(className != "") {
            newBot.PawnClass = class<Pawn>(DynamicLoadObject(className, class'Class'));
        } else if(newBot.PawnClass == None) {
            log("newBot.PawnClass is None");
            newBot.PawnClass = class<Pawn>(DynamicLoadObject("xGame.xPawn", class'Class'));
        }

        SpawnPlayer(newBot, startLocation, startRotation);
    } else {
        log("NewBot was none");
    }

    return NewBot;
}

function SpawnPlayer(RemoteBot newBot, optional vector startLocation, optional rotator startRotation) {
    local NavigationPoint startSpot;

    if(NewBot == None) {
        log("NewBot was none");
        return;
    }
    if(NewBot.Pawn != None) {
        log("Already had pawn");
        return;
    }

    startSpot = FindPlayerStart(NewBot);

    if(startLocation == vect(0,0,0)) {
        NewBot.Pawn = Spawn(GetDefaultPlayerClass(NewBot),,,StartSpot.Location,StartSpot.Rotation);
    } else {
        NewBot.Pawn = Spawn(NewBot.PawnClass,,,startLocation,startRotation);
    }
    log("PawnClass: "$NewBot.PawnClass);

    if ( NewBot.Pawn == None )
    {
        log("Couldn't spawn player of type "$NewBot.PawnClass$" at "$StartSpot);
        return;
    } else {
        log("Spawned player of type "$NewBot.PawnClass$" at "$StartSpot);
    }

    NewBot.Pawn.Anchor = startSpot;
    NewBot.Pawn.LastStartSpot = PlayerStart(startSpot);
    NewBot.Pawn.LastStartTime = Level.TimeSeconds;
    NewBot.PreviousPawnClass = NewBot.Pawn.Class;

    NewBot.Possess(NewBot.Pawn);
    NewBot.PawnClass = NewBot.Pawn.Class;

    NewBot.Squad = spawn(DeathMatch(Level.Game).DMSquadClass);
    if(NewBot.Squad == None) log("NewBot.Squad == None");

    NewBot.Pawn.PlayTeleportEffect(true, true);
    //	NewBot.ClientSetRotation(NewBot.Pawn.Rotation);
    AddDefaultInventory(NewBot.Pawn);
    TriggerEvent( StartSpot.Event, StartSpot, NewBot.Pawn );
    BroadcastLocalizedMessage(GameMessageClass, 1, NewBot.PlayerReplicationInfo);
    NewBot.GotoState('StartUp', 'Begin');
}

function string GetGameStatus()
{
    local string ib, as, ae;
    local string outStr;
    local Controller P;
    
    ib = theBotServer.ib;
    as = theBotServer.as;
    ae = theBotServer.ae;
    
    outStr = "GAM";
            
    outStr = ( outStr $ib$as$ "PlayerScores" );
    for ( P=Level.ControllerList; P!=None; P=P.NextController )
    {
        if( !P.PlayerReplicationInfo.bIsSpectator )
            outStr = ( outStr $ib$as$ P $ib$ P.PlayerReplicationInfo.Score $ae );
    }
    
    outStr = ( outStr $ae );                
                    
    return outStr;
}

function string GetGameInfo()
{
    local string ib, as, ae;
    local string outStr;
    
    ib = theBotServer.ib;
    as = theBotServer.as;
    ae = theBotServer.ae;
    
    //outStr = (ib$as$ "FragLimit" $ib$ $ae$ib$as$ "TimeLimit" $ib$ $ae);	
    outStr = (ib$as$ "TimeLimit" $ib$ TimeLimit $ae);   
                    
    return outStr;
}

function RestartPlayer( Controller aPlayer )
{
    if(aPlayer.IsA('RemoteBot')) {
        if(aPlayer.IsInState('Dying')) {
            log("BOTRESTRTPLAYER"@aPlayer);
            SpawnPlayer(RemoteBot(aPlayer));    
        }
    } else if (aPlayer.IsA('Player')){
        log("RESTARTPLAYER"@aPlayer);
        Super.RestartPlayer(aPlayer);
    }
}

function Killed( Controller Killer, Controller Killed, Pawn KilledPawn, class<DamageType> damageType )
{
    local string ib, as, ae;
    
    ib = theBotServer.ib;
    as = theBotServer.as;
    ae = theBotServer.ae;

    Killer.PlayerReplicationInfo.Score += 1.0;

    if(!Killed.IsA('RemoteBot')) {
        Super.Killed(Killer, Killed, KilledPawn, damageType);
    } else  if(Killed != None) 
        RemoteBot(Killed).myConnection.SendLine("DIE" $ib$as$ "Killer" $ib$ Killer $ae$ib$as$
                            "DamageType" $ib$ damageType $ae);
}

defaultproperties
{
     BotServerClass=USARBotAPI.BotServer
     VizServerClass=USARBotAPI.VizServer
     ComServerClass=USARBotAPI.ComServer
     RemoteBotConfigClass=USARBotAPI.RemoteBotInfo
     RemoteBotClass=USARBotAPI.RemoteBot;    
     NetWait=0
     CountDown=0
     DefaultEnemyRosterClass="XGame.xDMRoster"
     bPauseable=True
     AutoAim=0.930000
     GameSpeed=1.500000
     MaxPlayers=16
     GameName="Remote Bot DeathMatch"
     PlayerControllerClassName="USARBotAPI.ViewTestPlayerController"
}